home *** CD-ROM | disk | FTP | other *** search
/ The Games Machine 103 / XENIATGM103.iso / Shareware / GoLive 5.0 / MM9.Cab / F1477_ado.info5.asp.9B3B646D_CB56_4EAE_BAB7_3E7E8E41A649 < prev    next >
Text File  |  2000-08-17  |  9KB  |  322 lines
  1. <!-- #INCLUDE FILE="../include/utils.runtime5.asp" -->
  2. <!-- #INCLUDE FILE="../include/ado.runtime5.asp" -->
  3.  
  4. <script runat="server" language="VBScript">
  5.  
  6. ' *****************************************************************************
  7. '
  8. ' info/ado.info5.asp
  9. '
  10. ' Dynamic Link design time support for Microsoft ADO.
  11. '
  12. '
  13. ' COPYRIGHT (c) 1999-2000 Adobe Systems Incorporated. All rights reserved.
  14.  
  15. ' -----------------------------------------------------------------------------
  16. ' Return an XML document containing information about the databases
  17. ' in ../databases.    Valid requests are:
  18. '
  19. '        ado.info5.asp            return the available databases
  20. '            ex) http://localhost/golive/config/info/ado.info5.asp
  21. '        ado.info5.asp?db=<name>    return schema information about a given database
  22. '            ex) http://localhost/golive/config/info/ado.info5.asp?db=Magazine
  23.  
  24. RejectUnauthorizedCallers
  25. Response.ContentType = "text/xml"
  26. if False = RuntimeDebug then
  27.     on error resume next
  28. end if
  29.  
  30. if IsEmpty(Request("db")) then
  31.     WriteDatabases
  32. else
  33.     WriteDatabaseSchema Request("db")
  34. end if
  35.  
  36. if Err then
  37.     WriteError
  38. end if
  39.  
  40. ' -----------------------------------------------------------------------------
  41. ' Write out the list of available databases.  XML format:
  42. '
  43. '        <DATABASES>
  44. '            [<DATABASE>...]*
  45.  
  46. function WriteDatabases
  47.  
  48.     dim fileSystem
  49.     dim folder
  50.     dim file
  51.     dim fileName
  52.     dim prevFileName
  53.  
  54.     set fileSystem = CreateObject("Scripting.FileSystemObject")
  55.     set folder = fileSystem.GetFolder(GetDatabasePath())
  56.  
  57.     Response.Write "<DATABASES>" & vbNewLine
  58.     for each file in folder.files
  59.         select case ucase(fileSystem.GetExtensionName(file))
  60.             case "UDL", "DSN", "MDB", "XDB"
  61.                 fileName = fileSystem.GetBaseName(file)
  62.                 if fileName <> prevFileName then
  63.                     Response.Write "    <DATABASE>" & fileName & "</DATABASE>" & vbNewLine
  64.                     prevFileName = fileName
  65.                 end if
  66.         end select
  67.     next
  68.     Response.Write "</DATABASES>" & vbNewLine
  69.  
  70. end function
  71.  
  72. ' -----------------------------------------------------------------------------
  73. ' Write out the schema for a given database.  XML format is either:
  74. '        1. no types or sql parameters
  75. '        ex) http://localhost/golive/config/info/ado.info5.asp?db=Magazine
  76. '        <DATATYPES>
  77. '            [<DATATYPE>
  78. '               <TYPE_NAME>...
  79. '               <DATA_TYPE>...
  80. '               <IS_LONG>...
  81. '               <SEARCHABLE>...
  82. '               <LITERAL_PREFIX>...
  83. '               <LITERAL_SUFFIX>...]*
  84. '
  85. '        2. types parameter is * or comma-delimited list of table types to return
  86. '        ex) http://localhost/golive/config/info/ado.info5.asp?db=Magazine&types=*
  87. '        ex) http://localhost/golive/config/info/ado.info5.asp?db=Magazine&types=table,view
  88. '        <TABLES>
  89. '            [<TABLE>...]*
  90. '
  91. '        3. sql parameter gives a query but there is no records parameter
  92. '        ex) http://localhost/golive/config/info/ado.info5.asp?db=Magazine&sql=select%20*%20from%20Projects
  93. '        <COLUMNS>
  94. '            [<COLUMN>
  95. '                <COLUMN_NAME>...
  96. '                <DATA_TYPE>... 
  97. '                <ATTRIBUTES>...]*
  98. ' 
  99. '        4. records parameter is present (actual data, not schema information)
  100. '        ex) http://localhost/golive/config/info/ado.info5.asp?db=Magazine&sql=select%20*%20from%20Projects&records=0
  101. '        <ROWSET>
  102. '            [<ROW>
  103. '                [<fieldname>fieldvalue</fieldname>]*]*
  104.  
  105. '        5. keys parameter is primary key field
  106. '        ex) http://localhost/golive/config/info/ado.info5.asp?db=Magazine&keys=Projects
  107. '        <KEYS>
  108. '            [<PRIMAY_KEY>....
  109.  
  110. function WriteDatabaseSchema(db)
  111.  
  112.     dim connection
  113.  
  114.     set connection = CreateObject("ADODB.Connection")
  115.     connection.Open ConnectString(db)
  116.  
  117.     if IsEmpty(Request("sql")) then
  118.         DoOpenSchema connection 
  119.     else
  120.         AnalyzeRecordset connection.Execute(Request("sql"))
  121.     end if
  122.  
  123. end function
  124.  
  125. ' -----------------------------------------------------------------------------
  126. ' Handles schema requests that need OpenSchema
  127.  
  128. function DoOpenSchema(connection)
  129.  
  130.     if IsEmpty(Request("keys")) then
  131.         if IsEmpty(Request("types")) then
  132.             OpenTypesSchema connection
  133.         else
  134.             OpenTablesSchema connection, Request("types")
  135.         end if
  136.     else
  137.         OpenKeysSchema connection, Request("keys")
  138.     end if
  139.  
  140. end function
  141.  
  142. ' -----------------------------------------------------------------------------
  143. ' Get provider types
  144.  
  145. function OpenTypesSchema(connection)
  146.  
  147.     dim datatypes, typefields, field
  148.  
  149.     typefields = Array("TYPE_NAME", "DATA_TYPE", "IS_LONG", "SEARCHABLE", "LITERAL_PREFIX", "LITERAL_SUFFIX")
  150.  
  151.     set datatypes = connection.OpenSchema(adSchemaProviderTypes)
  152.  
  153.     Response.Write "<DATATYPES>" & vbNewLine
  154.     while not datatypes.EOF
  155.         dim typefield
  156.  
  157.         Response.Write "    <DATATYPE>" & vbNewLine
  158.  
  159.         for each typefield in typefields
  160.             set field = datatypes(typefield)
  161.             value = field.Value
  162.             if value = "null" then value = ""
  163.             Response.Write "        <" & field.Name & ">" & value & "</" & field.Name & ">" & vbNewLine
  164.         next
  165.  
  166.         Response.Write "    </DATATYPE>" & vbNewLine
  167.  
  168.         datatypes.MoveNext
  169.     wend
  170.     Response.Write "</DATATYPES>" & vbNewLine
  171.  
  172. end function
  173.  
  174. ' -----------------------------------------------------------------------------
  175. ' Get primary key fields
  176.  
  177. function OpenKeysSchema(connection, keys)
  178.     dim catalog, index
  179.     tableName = keys
  180.  
  181.     set catalog = CreateObject("ADOX.Catalog")
  182.     set catalog.ActiveConnection = connection
  183.  
  184.     Response.Write "<KEYS>" & vbNewLine
  185.     for each index in catalog.Tables( tableName ).Indexes
  186.         if False = testIndexColumns( index ) then
  187.             exit for
  188.         end if
  189.         if index.PrimaryKey = True then
  190.             for i = 0 to index.Columns.Count - 1
  191.                 Response.Write "    <PRIMARY_KEY>" & index.Columns(i).Name & "</PRIMARY_KEY>" & vbNewLine
  192.             next
  193.         end if
  194.     next
  195.     Response.Write "</KEYS>" & vbNewLine
  196.  
  197. end function
  198.  
  199. ' -----------------------------------------------------------------------------
  200. ' Get table names
  201.  
  202. function OpenTablesSchema(connection, typesString)
  203.  
  204.     dim tables
  205.     
  206.     if typesString = "*" then
  207.         set tables = connection.OpenSchema(adSchemaTables)
  208.         Response.Write "<TABLES>" & vbNewLine
  209.         while not tables.EOF
  210.             Response.Write "    <TABLE>" & tables("TABLE_NAME") & "</TABLE>" & vbNewLine
  211.             tables.MoveNext
  212.         wend
  213.         Response.Write "</TABLES>" & vbNewLine
  214.     else
  215.         dim types, weparse, i, j
  216.         weparse = False
  217.  
  218.         types = Split(typesString, ",")
  219.  
  220.         Response.Write "<TABLES>" & vbNewLine
  221.         on error resume next
  222.  
  223.         for i = LBound(types) to UBound(types)
  224.             set tables = connection.OpenSchema(adSchemaTables, Array(Empty, Empty, Empty, types(i)))
  225.             if Err then
  226.                 we parse = True
  227.                 exit for
  228.             end if
  229.  
  230.             while not tables.EOF
  231.                 Response.Write "    <TABLE>" & tables("TABLE_NAME") & "</TABLE>" & vbNewLine
  232.                 tables.MoveNext
  233.             wend
  234.         next
  235.  
  236.         if weparse then
  237.             set tables = connection.OpenSchema(adSchemaTables)
  238.             while not tables.EOF
  239.                 for j = i to UBound(types)
  240.                     if types(j) = tables("TABLE_TYPE") then
  241.                         Response.Write "    <TABLE>" & tables("TABLE_NAME") & "</TABLE>" & vbNewLine
  242.                     end if
  243.                 next
  244.  
  245.                 tables.MoveNext
  246.             wend
  247.         end if
  248.  
  249.         Response.Write "</TABLES>" & vbNewLine
  250.     end if
  251.  
  252. end function
  253.  
  254. ' -----------------------------------------------------------------------------
  255. ' Handles schema requests from recordsets
  256.  
  257. function AnalyzeRecordset(rs)
  258.  
  259.     dim fields, field, recordsString
  260.     set fields = rs.Fields
  261.     
  262.     recordsString = Request("records")
  263.     if IsEmpty(recordsString) then
  264.         dim i
  265.  
  266.         Response.Write "<COLUMNS>" & vbNewLine
  267.  
  268.         for i = 0 to fields.Count - 1
  269.             set field = fields(i)
  270.             Response.Write "    <COLUMN>" & vbNewLine
  271.             Response.Write "        <COLUMN_NAME>" & field.Name & "</COLUMN_NAME>" & vbNewLine
  272.             Response.Write "        <DATA_TYPE>" & field.Type & "</DATA_TYPE>" & vbNewLine
  273.             Response.Write "        <ATTRIBUTES>" & field.Attributes & "</ATTRIBUTES>" & vbNewLine
  274.             Response.Write "    </COLUMN>" & vbNewLine
  275.         next
  276.  
  277.         Response.Write "</COLUMNS>" & vbNewLine
  278.     else
  279.         dim records
  280.         records = split(recordsString, ",")
  281.         rs.Move records(0)
  282.         
  283.         Response.Write "<ROWSET>" & vbNewLine
  284.         
  285.         do
  286.             Response.Write "    <ROW>" & vbNewLine
  287.             for i = 0 to fields.Count - 1
  288.                 set field = fields(i)
  289.                 Response.Write "        <" & field.Name & ">" & field.Value & "</" & field.Name & ">" & vbNewLine
  290.             next
  291.             Response.Write "    </ROW>" & vbNewLine
  292.             
  293.             if CLng(records(0)) >= CLng(records(ubound(records))) then exit do
  294.             records(0) = records(0) + 1
  295.             rs.MoveNext
  296.         loop while not (rs.EOF or Err)
  297.         
  298.         Response.Write "</ROWSET>" & vbNewLine
  299.     end if
  300.  
  301. end function
  302.  
  303. ' -----------------------------------------------------------------------------
  304. ' Write out an error message as XML.
  305.  
  306. function WriteError
  307.  
  308.     dim qt
  309.  
  310.     qt = chr(34)
  311.     Response.Write "<ERROR" 
  312.     Response.Write " Number="        & qt    & Err.Number            & qt
  313.     Response.Write " Source="        & qt    & Err.Source            & qt
  314.     Response.Write " Description="    & qt    & Err.Description        & qt
  315.     Response.Write " HelpFile="        & qt    & Err.HelpFile            & qt
  316.     Response.Write " HelpContext="    & qt    & Err.HelpContext        & qt
  317.     Response.Write "/>" & vbNewLine
  318.     
  319. end function
  320.  
  321. </script>
  322.